home *** CD-ROM | disk | FTP | other *** search
/ MacWorld 1997 January / Macworld (1997-01).dmg / Shareware World / Fonts / Metafont / Inputs / romanu.mf < prev    next >
Text File  |  1994-08-19  |  35KB  |  739 lines
  1. % Computer Modern Roman upper case:
  2. % These letters were originally coded by D. E. Knuth in November, 1979,
  3. % inspired by the Monotype faces used in {\sl The Art of Computer Programming}.
  4. % Sans serif designs by Richard Southall were added in April, 1982.
  5. % The programs were revised for the new \MF\ conventions in 1985.
  6.  
  7. % Character codes \0101 through \0132 are generated.
  8.  
  9. cmchar "The letter A";
  10. beginchar("A",13u#,cap_height#,0);
  11. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  12. numeric left_stem,right_stem,outer_jut,alpha;
  13. right_stem=cap_stem-stem_corr;
  14. left_stem=min(cap_hair if hefty: -3stem_corr fi,right_stem);
  15. outer_jut=.8cap_jut; x1l=w-x4r=l+letter_fit+outer_jut+.5u; y1=y4=0;
  16. x2-x1=x4-x3; x3r=x2r+apex_corr; y2=y3=h+apex_o+apex_oo;
  17. alpha=diag_ratio(2,left_stem,y2-y1,x4r-x1l-apex_corr);
  18. penpos1(alpha*left_stem,0); penpos2(alpha*left_stem,0);
  19. penpos3(alpha*right_stem,0); penpos4(alpha*right_stem,0);
  20. z0=whatever[z1r,z2r]=whatever[z3l,z4l];
  21. if y0<h-cap_notch_cut: y0:=h-cap_notch_cut;
  22.  fill z0+.5right{down}...{z4-z3}diag_end(3l,4l,1,1,4r,3r)
  23.   --diag_end(4r,3r,1,1,2l,1l)--diag_end(2l,1l,1,1,1r,2r){z2-z1}
  24.   ...{up}z0+.5left--cycle; % left and right diagonals
  25. else: fill z0--diag_end(0,4l,1,1,4r,3r)--diag_end(4r,3r,1,1,2l,1l)
  26.   --diag_end(2l,1l,1,1,1r,0)--cycle; fi % left and right diagonals
  27. penpos5(whatever,angle(z2-z1)); z5=whatever[z1,z2];
  28. penpos6(whatever,angle(z3-z4)); z6=whatever[z3,z4]; y6=y5;
  29. if hefty: y5r else: y5 fi =5/12y0;
  30. y5r-y5l=y6r-y6l=cap_band; penstroke z5e--z6e; % bar line
  31. if serifs: numeric inner_jut; pickup tiny.nib;
  32.  prime_points_inside(1,2); prime_points_inside(4,3);
  33.  if rt x1'r+cap_jut+.5u+1<=lft x4'l-cap_jut: inner_jut=cap_jut;
  34.  else: rt x1'r+inner_jut+.5u+1=lft x4'l-inner_jut; fi
  35.  dish_serif(1',2,a,1/2,outer_jut,b,.6,inner_jut)(dark);  % left serif
  36.  dish_serif(4',3,c,1/2,inner_jut,d,1/3,outer_jut); fi  % right serif
  37. penlabels(0,1,2,3,4,5,6); endchar;
  38.  
  39. cmchar "The letter B";
  40. beginchar("B",12.5u#,cap_height#,0);
  41. italcorr .75cap_height#*slant-.5u#;
  42. adjust_fit(cap_serif_fit#,0);
  43. numeric left_stem,right_curve,middle_weight;
  44. left_stem=cap_stem-hround 2stem_corr; middle_weight=.6vair+.5;
  45. pickup tiny.nib; pos1(left_stem,0); pos2(left_stem,0);
  46. lft x1l=lft x2l=hround max(2u,3u-.5left_stem); top y1=h; bot y2=0;
  47. filldraw stroke z1e--z2e; % stem
  48. penpos3(cap_band,90); penpos4(cap_band,90);
  49. penpos6(middle_weight,-90); penpos7(middle_weight,-90);
  50. penpos8(middle_weight,90); penpos9(middle_weight,90);
  51. penpos5(right_curve-stem_corr,0); penpos10(right_curve,0);
  52. penpos11(cap_band,-90); penpos12(cap_band,-90);
  53. z3r=top z1; y4=y3; y5=.5[y4,y6]; y6=y7; y7l-y8l=vair;
  54. z12r=bot z2; y11=y12; y10=.5[y11,y9]; y8=y9; .5[y7l,y8l]=.52h;
  55. x4=x6; x9=x11=x4+.5u; x7=x8=x1; x9l:=x4+.25u;
  56. x5r=hround(w-1.5u); x10r=hround(w-u);
  57. if serifs: right_curve=cap_curve-stem_corr; x4=.5[x1,w-1.5u];
  58. else: right_curve=cap_curve-3stem_corr; x4=.5[x1,w-2.5u];
  59.  x4l:=x4l-.5u; x9l:=x9l-.5u; fi
  60. x6l:=x6l-.5u; x11l:=x11l-.5u;
  61. fill stroke z3e..super_arc.e(4,5) & super_arc.e(5,6)..z7e;  % upper lobe
  62. fill stroke z8e..super_arc.e(9,10) & super_arc.e(10,11)..z12e;  % lower lobe
  63. if serifs: nodish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut);  % upper serif
  64.  nodish_serif(2,1,c,1/3,cap_jut,d,1/3,.5cap_jut); fi  % lower serif
  65. math_fit(0,.5ic#); penlabels(1,2,3,4,5,6,7,8,9,10,11,12); endchar;
  66.  
  67. cmchar "The letter C";
  68. if serifs: beginchar("C",13u#,cap_height#,0);
  69.  italcorr cap_height#*slant-.5u#;
  70.  adjust_fit(0,0);
  71.  pickup fine.nib; pos1(cap_hair,0); pos2(cap_band,90);
  72.  pos3(cap_curve,180); pos4(cap_band,270); pos5(hair,360);
  73.  rt x1r=rt x5r=hround(w-u); lft x3r=hround u; x2=x4=.55[x3,x1];
  74.  top y2r=h+o; bot y4r=-o; y3=.5[y2,y4];
  75.  bot y1=min(vround max(.6h,x_height-.5vair),bot y2l-eps);
  76.  y5=max(good.y .95(h-y1),y4l+eps);
  77.  (x2l',y2l)=whatever[z2r,z1l]; x2l:=min(x2l',x2l+.5u);
  78.  (x4l',y4l)=whatever[z4r,z5l]; x4l:=min(x4l',x4l+.5u);
  79.  filldraw stroke z1e{x2-x1,10(y2-y1)}
  80.   ...pulled_arc.e(2,3) & pulled_arc.e(3,4)...{up}z5e; % arc
  81.  pos6(.3[fine.breadth,cap_hair],0); x6r=x1r; top y6=h+o;
  82.  x1r-x1'=2cap_curve-fine; y1'=y1;
  83.  path upper_arc; upper_arc=z1{x2-x1,10(y2-y1)}..z2{left};
  84.  numeric t; t=xpart(upper_arc intersectiontimes (z6l--z1'));
  85.  filldraw z1r--z6r--z6l--subpath(t,0) of upper_arc--cycle; % barb
  86. else: beginchar("C",11.5u#,cap_height#,0);
  87.  italcorr cap_height#*slant-.5u#;
  88.  adjust_fit(0,0);
  89.  pickup fine.nib; pos1(1.2flare,80); pos2(slab,90);
  90.  pos3(cap_curve,180); pos4(slab,270); pos5(flare,275);
  91.  rt x1r=hround(w-1.1u); x2=x4=.5w+1.25u;
  92.  lft x3r=hround max(u,2u-.5cap_curve); rt x5r=hround(w-.9u);
  93.  top y1r=vround .95h+o; top y2r=h+o; y3=.5h;
  94.  bot y4r=-o; bot y5r=vround .08h-o; y5l:=good.y y5l; x5l:=good.x x5l;
  95.  filldraw stroke rterm.e(2,1,right,.9,4) & super_arc.e(2,3)
  96.   & super_arc.e(3,4) & term.e(4,5,right,.8,4); fi % arc and terminals
  97. math_fit(-.3cap_height#*slant-.5u#,.5ic#);
  98. penlabels(1,1',2,3,4,5,6); endchar;
  99.  
  100. cmchar "The letter D";
  101. beginchar("D",13.5u#,cap_height#,0);
  102. italcorr .7cap_height#*slant-.5u#;
  103. adjust_fit(cap_serif_fit#,0);
  104. pickup tiny.nib; pos1(cap_stem',0); pos2(cap_stem',0);
  105. lft x1l=lft x2l=hround max(2u,3u-.5cap_stem'); top y1=h; bot y2=0;
  106. filldraw stroke z1e--z2e; % stem
  107. penpos3(cap_band,90); penpos4(cap_band,90);
  108. penpos5(cap_curve-stem_corr,0);
  109. penpos6(cap_band,-90); penpos7(cap_band,-90);
  110. z3r=top z1; y4=y3; y5=.51[y4,y6]; y6=y7;
  111. z7r=bot z2; x4=x6=.5w+.25u; x5r=hround(w-u);
  112. x4l:=x6l:=x4-.25cap_curve;
  113. fill stroke z3e..pulled_arc.e(4,5) & pulled_arc.e(5,6)..z7e;  % lobe
  114. if serifs: nodish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut);  % upper serif
  115.  nodish_serif(2,1,c,1/3,cap_jut,d,1/3,.5cap_jut); fi  % lower serif
  116. math_fit(0,ic#-.5u#); penlabels(1,2,3,4,5,6,7); endchar;
  117.  
  118. cmchar "The letter E";
  119. beginchar("E",12u#-width_adj#,cap_height#,0);
  120. italcorr cap_height#*slant-beak_jut#-.5u#;
  121. adjust_fit(cap_serif_fit#,0);
  122. h:=vround(h-stem_corr);
  123. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  124. lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); top y1=h; bot y2=0;
  125. filldraw stroke z1e--z2e; % stem
  126. pickup crisp.nib; pos3(slab,90); pos4(hair,0);
  127. top y3r=h; x3=x1; rt x4r=hround(w-u); y4=good.y(y3l-beak)-eps;
  128. arm(3,4,e,beak_darkness,beak_jut);  % upper arm and beak
  129. pos5(cap_bar,-90); pos6(hair,0);
  130. top y5l=vround(.52[y2,y1]+.5cap_bar); x5=x1;
  131. pos0(cap_bar,90); pos7(hair,0);
  132. z0=z5; x6=x7; y6-y5l=y0l-y7;
  133. if serifs: rt x6r=hround(w-4.4u+.5hair); y6=good.y(y5l+.6beak)+eps;
  134.  rt x9r=hround(w-.5u);
  135. else: rt x6r=hround(w-1.5u); y6=y5l+eps; rt x9r=hround(w-.75u); fi
  136. arm(5,6,f,beak_darkness,0); arm(0,7,g,beak_darkness,0);  % middle arm and serif
  137. pos8(slab if not serifs:+2stem_corr fi,-90); pos9(hair,0);
  138. bot y8r=0; x8=x2; y9=good.y(y8l+7/6beak)+eps;
  139. arm(8,9,h,beak_darkness,1.5beak_jut);  % lower arm and beak
  140. if serifs: nodish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut);  % upper serif
  141.  nodish_serif(2,1,c,1/3,cap_jut,d,1/3,.5cap_jut); fi  % lower serif
  142. math_fit(0,.5ic#); penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  143.  
  144. cmchar "The letter F";
  145. beginchar("F",11.5u#-width_adj#,cap_height#,0);
  146. italcorr cap_height#*slant-beak_jut#-.25u#;
  147. adjust_fit(cap_serif_fit#,0);
  148. h:=vround(h-stem_corr);
  149. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  150. lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); top y1=h; bot y2=0;
  151. filldraw stroke z1e--z2e; % stem
  152. pickup crisp.nib; pos3(slab,90); pos4(hair,0);
  153. top y3r=h; x3=x1; rt x4r=hround(w-.75u); y4=good.y(y3l-beak)-eps;
  154. arm(3,4,e,beak_darkness,beak_jut);  % upper arm and beak
  155. pos5(cap_bar,-90); pos6(hair,0);
  156. top y5l=vround(.5[y2,y1]+.5cap_bar); x5=x1;
  157. pos0(cap_bar,90); pos7(hair,0);
  158. z0=z5; x6=x7; y6-y5l=y0l-y7;
  159. if serifs: rt x6r=hround(w-4u+.5hair); y6=good.y(y5l+.6beak)+eps;
  160.  rt x9r=hround(w-.5u);
  161. else: rt x6r=hround(w-1.5u); y6=y5l+eps; rt x9r=hround(w-.75u); fi
  162. arm(5,6,f,beak_darkness,0); arm(0,7,g,beak_darkness,0);  % middle arm and serif
  163. if serifs: nodish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut);  % upper serif
  164.  dish_serif(2,1,c,1/3,cap_jut,d,1/3,1.25cap_jut); fi  % lower serif
  165. math_fit(0,ic#-2.5u#); penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  166.  
  167. cmchar "The letter G";
  168. if serifs: beginchar("G",14u#,cap_height#,0);
  169.  italcorr cap_height#*slant-1.5u#-.5cap_serif_fit#;
  170.  adjust_fit(0,.5cap_serif_fit#);
  171.  pickup tiny.nib; pos0(cap_stem,0); pos7(cap_stem,0);
  172.  rt x0r=hround(w-2u); y0=good.y(.1[bar_height,x_height]+1); x7=x0;
  173.  pickup fine.nib;
  174.  if hefty: bot y7=0; pos5(cap_stem,0); x5=x0; top y5=tiny.top y0;
  175.  else: pos5(cap_hair,0); pos8(cap_stem,0);
  176.   y7=.5bar_height; z5l=z8l; z8=z7; x9=x8r; bot y9=0;
  177.   filldraw z8l{down}..{4(x9-x8),y9-y8}z9--z8r--cycle; fi % spur
  178.  pos1(cap_hair,0); pos2(cap_band,90);
  179.  pos3(cap_curve,180); pos4(cap_band,270);
  180.  rt x1r=hround(w-2u); lft x3r=hround u; x2=x4=.55[x3,x1];
  181.  top y2r=h+o; bot y4r=-o; y3=.5[y2,y4];
  182.  bot y1=min(vround max(.6h,x_height-.5vair),bot y2l-eps);
  183.  (x2l',y2l)=whatever[z2r,z1l]; x2l:=min(x2l',x2l+.5u);
  184.  (x4l',y4l)=whatever[z4r,z5l]; x4l:=min(x4l',x4l+.5u);
  185.  filldraw stroke z1e{x2-x1,10(y2-y1)}
  186.   ...pulled_arc.e(2,3) & pulled_arc.e(3,4)...z5e{up}; % arc
  187.  pos6(.3[fine.breadth,cap_hair],0); x6r=x1r; top y6=h+o;
  188.  x1r-x1'=2cap_curve-fine; y1'=y1;
  189.  path upper_arc; upper_arc=z1{x2-x1,10(y2-y1)}..z2{left};
  190.  numeric t; t=xpart(upper_arc intersectiontimes (z6l--z1'));
  191.  filldraw z1r--z6r--z6l--subpath(t,0) of upper_arc--cycle; % barb
  192.  pickup tiny.nib; filldraw stroke z0e--z7e;  % stem
  193.  dish_serif(0,7,a,1/3,max(cap_jut,2.25u),b,1/3,1.25u);  % serif
  194.  math_fit(-.3cap_height#*slant-.5u#,ic#);
  195. else: beginchar("G",12u#,cap_height#,0);
  196.  italcorr cap_height#*slant-.5u#;
  197.  adjust_fit(0,0);
  198.  pickup fine.nib; pos1(1.2flare,80); pos2(slab,90);
  199.  pos3(cap_curve,180); pos4(slab,270); pos5(flare,270);
  200.  rt x1r=hround(w-1.35u); x2=x4=.5w+u;
  201.  lft x3r=hround max(u,2u-.5cap_curve); rt x5l=hround(w-1.2u);
  202.  top y1r=vround .93h+o; top y2r=h+o; y3=.5h;
  203.  bot y4r=-o; bot y5r=vround .07h-o;
  204.  filldraw stroke rterm.e(2,1,right,.9,4)&super_arc.e(2,3)
  205.   & super_arc.e(3,4) & term.e(4,5,right,1,4); % arc and terminals
  206.  pos0(stem,0); pos7(stem,0);
  207.  z7r=z5r; x0=x7; top y0=1+vround .35[bar_height,x_height];
  208.  filldraw stroke z0e--z7e;  % stem
  209.  pos8(cap_bar,90); pos9(cap_bar,90);
  210.  z0r=z9r; y8=y9; lft x8=hround x4;
  211.  filldraw stroke z8e--z9e;  % bar
  212.  math_fit(-.3cap_height#*slant-.5u#,.5ic#); fi
  213. penlabels(0,1,1',2,3,4,5,6,7,8,9); endchar;
  214.  
  215. cmchar "The letter H";
  216. beginchar("H",13u#+width_adj#,cap_height#,0);
  217. italcorr cap_height#*slant-cap_serif_fit#+cap_jut#-2.5u#+min(.5cap_stem#,u#);
  218. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  219. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  220. pos3(cap_stem,0); pos4(cap_stem,0);
  221. lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); x3=x4=w-x1;
  222. top y1=top y3=h; bot y2=bot y4=0;
  223. filldraw stroke z1e--z2e; % left stem
  224. filldraw stroke z3e--z4e; % right stem
  225. penpos5(cap_bar,90); penpos6(cap_bar,90);
  226. x5=x1; x6=x3; y5=y6=.52h;
  227. fill stroke z5e--z6e;  % bar
  228. if serifs: numeric inner_jut;
  229.  if rt x1r+cap_jut+.5u+1<=lft x3l-cap_jut: inner_jut=cap_jut;
  230.  else: rt x1r+inner_jut+.5u+1=lft x3l-inner_jut; fi
  231.  dish_serif(1,2,a,1/3,cap_jut,b,1/3,inner_jut);  % upper left serif
  232.  dish_serif(2,1,c,1/3,cap_jut,d,1/3,inner_jut); % lower left serif
  233.  dish_serif(3,4,e,1/3,inner_jut,f,1/3,cap_jut);  % upper left serif
  234.  dish_serif(4,3,g,1/3,inner_jut,h,1/3,cap_jut); fi  % lower left serif
  235. math_fit(0,.5ic#); penlabels(1,2,3,4,5,6); endchar;
  236.  
  237. cmchar "The letter I";
  238. beginchar("I",max(6u#,4u#+cap_stem#),cap_height#,0);
  239. italcorr cap_height#*slant-.25u#;
  240. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  241. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  242. lft x1l=lft x2l=hround(.5w-.5cap_stem); top y1=h; bot y2=0;
  243. filldraw stroke z1e--z2e; % stem
  244. if serifs: dish_serif(1,2,a,1/3,1.05cap_jut,b,1/3,1.05cap_jut);  % upper serif
  245.  dish_serif(2,1,c,1/3,1.05cap_jut,d,1/3,1.05cap_jut);  fi % lower serif
  246. math_fit(0,.5ic#); penlabels(1,2); endchar;
  247.  
  248. cmchar "The letter J";
  249. beginchar("J",9u#,cap_height#,0);
  250. italcorr cap_height#*slant-cap_serif_fit#
  251.  +.75cap_jut#-2.5u#+min(.5cap_stem#,u#);
  252. adjust_fit(0,cap_serif_fit#);
  253. pickup tiny.nib; pos1(cap_stem',0); pos2(cap_stem',0);
  254. top y1=h; rt x1r=hround(w-2u); x2=x1; y2=.21h;
  255. if serifs: pos3(vair,-90); pos4(cap_hair,-180);
  256.  pos5(flare+(cap_stem-stem),-180);
  257.  bot y3r=-o; x3=.5[x4,x2]; y5=1/6h; rt x5l=hround 2.75u; z5r=z4r;
  258.  filldraw stroke z1e--z2e&super_arc.e(2,3);  % stem and arc
  259.  dish_serif(1,2,a,1/3,1.3cap_jut,b,1/3,.75cap_jut);  % serif
  260.  pickup tiny.nib; bulb(3,4,5);  % bulb
  261. else: filldraw stroke z1e--z2e;  % stem
  262.  pickup fine.nib; pos3(cap_stem',0); z3=z2;
  263.  pos4(flare,angle(6.5u,-h)); pos5(1.1flare,-100);
  264.  bot y4r=-o; x4r=.5[x5r,x3r]; lft x5r=hround.75u; bot y5r=vround.06h-o;
  265.  filldraw stroke z3e{down}....term.e(4,5,left,1,4); fi % arc and terminal
  266. math_fit(0,.5ic#-.5u#); penlabels(1,2,3,4,5); endchar;
  267.  
  268. cmchar "The letter K";
  269. beginchar("K",13.5u#,cap_height#,0);
  270. italcorr cap_height#*slant-.5u#;
  271. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  272. numeric right_jut,stem[],alpha[];
  273. if serifs: right_jut=.6cap_jut;
  274. else: right_jut=.4tiny; fi
  275. pickup tiny.nib; pos1(fudged.cap_stem,0); pos2(fudged.cap_stem,0);
  276. lft x1l=lft x2l=hround max(2u,3u-.5fudged.cap_stem); top y1=h; bot y2=0;
  277. filldraw stroke z1e--z2e; % stem
  278. stem2=max(tiny.breadth,fudged.cap_stem-3stem_corr);
  279. stem1=max(tiny.breadth,fudged.hair if hefty:-3stem_corr fi);
  280. top y3=h; rt x3r=hround(r-letter_fit-u-right_jut);
  281. bot y6=0; rt x6r=hround(r-letter_fit-.75u-right_jut);
  282. x4=x1; y4=1/3h;
  283. alpha1=diag_ratio(1,.5(stem1-tiny),y3-y4,x3r-x4);
  284. penpos3(alpha1*(stem1-tiny),0); penpos4(whatever,-90);
  285. alpha2=diag_ratio(1,.5(stem2-tiny),y1-y6,x6r-x1);
  286. penpos6(alpha2*(stem2-tiny),0);
  287. forsuffixes $=l,r: y3'$=h; y6'$=0; z4$=z3'$+whatever*(z3-z4);
  288.  z5$=z6'$+whatever*(z1-z6)=whatever[z3,z4]; endfor
  289. z5=.5[z5l,z5r];
  290. z3'r=z3r+penoffset z3-z4 of currentpen+whatever*(z3-z4);
  291. % we have also |z3'l=z3l+penoffset z4-z3 of currentpen+whatever*(z3-z4)|;\]
  292. z6'r=z6r+penoffset z1-z6 of currentpen+whatever*(z1-z6);
  293. z6'l=z6l+penoffset z6-z1 of currentpen+whatever*(z1-z6);
  294. fill z4r--diag_end(4r,3'r,1,.5,3'l,4l)--z4l--cycle;  % upper diagonal
  295. fill z5l--diag_end(5l,6'l,.5,1,6'r,5r)--z5r--cycle;  % lower diagonal
  296. if serifs: numeric inner_jut;
  297.  if rt x2r+cap_jut+.5u+1<=lft x6l-cap_jut: inner_jut=cap_jut;
  298.  else: rt x2r+cap_jut+.5u+1=lft x6l-inner_jut; fi
  299.  dish_serif(1,2,a,1/3,cap_jut,b,1/3,cap_jut); % upper stem serif
  300.  dish_serif(2,1,c,1/3,cap_jut,d,1/3,cap_jut);  % lower stem serif
  301.  dish_serif(3,4,e,2/3,1.2cap_jut,f,1/2,right_jut)(dark); % upper diagonal serif
  302.  dish_serif(6,5,g,1/2,inner_jut,h,1/3,right_jut)(dark);fi % lower diagonal serif
  303. math_fit(0,.5ic#); penlabels(1,2,3,4,5,6); endchar;
  304.  
  305. cmchar "The letter L";
  306. beginchar("L",11u#-width_adj#,cap_height#,0);
  307. adjust_fit(cap_serif_fit#,0);
  308. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  309. lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); top y1=h; bot y2=0;
  310. filldraw stroke z1e--z2e; % stem
  311. pickup crisp.nib; pos3(slab,-90); pos4(hair,0);
  312. bot y3r=0; x3=x2; y4=y3l+7/6beak+eps; rt x4r=hround(w-.75u);
  313. arm(3,4,e,1.2beak_darkness,beak_jut);  % lower arm and beak
  314. if serifs: dish_serif(1,2,a,1/3,cap_jut,b,1/3,1.25cap_jut);  % upper serif
  315.  nodish_serif(2,1,c,1/3,cap_jut,d,1/3,.5cap_jut); fi  % lower serif
  316. math_fit(0,u#); penlabels(1,2,3,4); endchar;
  317.  
  318. cmchar "The letter M";
  319. beginchar("M",16u#+width_adj#,cap_height#,0);
  320. italcorr cap_height#*slant-cap_serif_fit#+cap_jut#-2.5u#+min(.5cap_stem#,u#);
  321. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  322. numeric stem[]; % thicknesses of the four strokes
  323. stem1=hround(fudged.hair+stem_corr);
  324. stem2=hround(fudged.cap_stem-4stem_corr);
  325. stem3=hround(fudged.hair-stem_corr);
  326. stem4=hround(fudged.cap_stem-3stem_corr);
  327. if stem4<stem1: stem4:=stem1; fi
  328. pickup tiny.nib; pos1(stem1,0); pos2(stem1,0);
  329. pos3(stem4,0); pos4(stem4,0);
  330. x1=x2; x3=x4; x1l=w-x3r; rt x3r=hround min(w-2u,w-3u+.5stem4);
  331. top y1=top y3=h; bot y2=bot y4=0;
  332. filldraw stroke z1e--z2e; % left stem
  333. filldraw stroke z3e--z4e; % right stem
  334. penpos5(stem2,0); penpos6(stem2,0); penpos7(stem3,0); penpos8(stem3,0);
  335. x5l=x1; x6l=x7l; x8=lft x3l; x6-x5=x8-x7; y5=y8=h; y6=y7;
  336. if hefty: y6=if monospace: vround 1/3h else: o fi;
  337.  numeric upper_notch,lower_notch;
  338.  upper_notch=h-cap_notch_cut; lower_notch=y6+cap_notch_cut;
  339.  x1'=rt x1r; z1'=whatever[z5l,z6l]; x3'=lft x3l; z3'=whatever[z7r,z8r];
  340.  z0=whatever[z5r,z6r]=whatever[z7l,z8l];
  341.  fill z5l..
  342.   if y1'<upper_notch: {right}(x1'+1,upper_notch){down}... fi
  343.   {z6-z5}diag_in(5l,6l,1,6r)..diag_out(7l,1,7r,8r){z8-z7}
  344.   if y3'<upper_notch: ...{up}(x3'-1,upper_notch){right} fi
  345.   ..z8r--diag_out(8r,1,8l,7l){z7-z8}
  346.   if y0<=lower_notch: ..{z7-z8}z0{z5-z6}..
  347.   else: ...{down}(x0+.5,lower_notch)--(x0-.5,lower_notch){up}... fi
  348.   {z5-z6}diag_in(6r,5r,1,5l)--cycle;  % diagonals
  349. else: y6=0; z0=whatever[z5r,z6r]=whatever[z7l,z8l];
  350.  fill z5l..{z6-z5}diag_in(5l,6l,1,6r)..diag_out(7l,1,7r,8r){z8-z7}
  351.   ..z8r--diag_out(8r,1,8l,7l){z7-z8}..{z7-z8}z0{z5-z6}
  352.   ..{z5-z6}diag_in(6r,5r,1,5l)--cycle; fi  % diagonals
  353. if serifs: serif(1,2,a,1/3,-cap_jut);  % upper left serif
  354.  dish_serif(2,1,b,1/2,cap_jut,c,1/2,cap_jut)(dark); % lower left serif
  355.  serif(3,4,d,1/3,cap_jut); %  upper right serif
  356.  dish_serif(4,3,e,1/3,cap_jut,f,1/3,cap_jut); fi  % lower right serif
  357. math_fit(0,max(.5ic#-.5u#,0));
  358. penlabels(0,1,1',2,3,3',4,5,6,7,8); endchar;
  359.  
  360. cmchar "The letter N";
  361. beginchar("N",13u#+width_adj#,cap_height#,0);
  362. italcorr cap_height#*slant-cap_serif_fit#+cap_jut#-2.5u#+min(.5cap_stem#,u#);
  363. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  364. numeric thin_stem; thin_stem=hround(fudged.hair+stem_corr);
  365. pickup tiny.nib; pos1(thin_stem,0); pos2(thin_stem,0);
  366. pos3(thin_stem,0); pos4(thin_stem,0);
  367. pickup tiny.nib; top y1=top y3=h; bot y2=bot y4=0;
  368. x1=x2; x3=x4; x1l=w-x3r;
  369. rt x3r=hround min(w-2u,w-3u+.5fudged.cap_stem);
  370. filldraw stroke z1e--z2e; % left stem
  371. filldraw stroke z3e--z4e; % right stem
  372. if hefty: penpos5(fudged.cap_stem,0); penpos6(fudged.cap_stem,0);
  373.  x5l=x1; x6r=x4; y5=h; y6=0;
  374.  numeric upper_notch,lower_notch;
  375.  upper_notch=h-cap_notch_cut; lower_notch=cap_notch_cut;
  376.  x1'=rt x1r; z1'=whatever[z5l,z6l]; x4'=lft x4l; z4'=whatever[z5r,z6r];
  377.  fill z5l..
  378.   if y1'<upper_notch: {right}(x1'+1,upper_notch){down}... fi
  379.   {z6-z5}diag_in(5l,6l,1,6r)--z6r..
  380.   if y4'>lower_notch: {left}(x4'-1,lower_notch){up}... fi
  381.   {z5-z6}diag_in(6r,5r,1,5l)--cycle;  % diagonal
  382. else: penpos5(whatever,0); penpos6(whatever,90);
  383.  z5l=z1l; z6l=z4l;
  384.  z7=z6l+(max(eps,cap_stem-3stem_corr-tiny),0) rotated (angle(z5l-z6l)-90);
  385.  z5r=z7+whatever*(z5l-z6l); z6r=z7+whatever*(z5l-z6l);
  386.  filldraw stroke z5e..z6e; fi  % diagonal
  387. if serifs: if hefty: serif(1,2,a,1/3,-cap_jut); % upper left serif
  388.  else: serif(5,6,a,1/3,-cap_jut); fi  % upper left serif
  389.  dish_serif(2,1,b,1/2,cap_jut,c,1/2,cap_jut)(dark); % lower left serif
  390.  dish_serif(3,4,e,1/2,cap_jut,f,1/2,cap_jut)(dark); fi  % upper right serif
  391. math_fit(0,max(.5ic#-.5u#,0)); penlabels(1,1',2,3,4,4',5,6,7); endchar;
  392.  
  393. cmchar "The letter O";
  394. beginchar("O",14u#-width_adj#,cap_height#,0);
  395. italcorr .7cap_height#*slant-.5u#;
  396. adjust_fit(0,0);
  397. penpos1(vair',90); penpos3(vround(vair+1.5vair_corr),-90);
  398. penpos2(cap_curve,180); penpos4(cap_curve,0);
  399. if monospace: x2r=hround 1.5u;
  400.  interim superness:=sqrt superness;  % make |"O"|, not |"0"|
  401. else: x2r=hround u; fi
  402. x4r=w-x2r; x1=x3=.5w; y1r=h+o; y3r=-o;
  403. y2=y4=.5h-vair_corr; y2l:=y4l:=.52h;
  404. penstroke pulled_super_arc.e(1,2)(.5superpull)
  405.  & pulled_super_arc.e(2,3)(.5superpull)
  406.  & pulled_super_arc.e(3,4)(.5superpull)
  407.  & pulled_super_arc.e(4,1)(.5superpull) & cycle;  % bowl
  408. math_fit(-.3cap_height#*slant-.5u#,ic#-.5u#); penlabels(1,2,3,4); endchar;
  409.  
  410. cmchar "The letter P";
  411. beginchar("P",12u#,cap_height#,0);
  412. italcorr .75cap_height#*slant-.5u#;
  413. adjust_fit(cap_serif_fit#,0);
  414. pickup tiny.nib; penpos1(cap_stem'-tiny,0); penpos2(cap_stem-tiny,0);
  415. pos0(cap_stem',0); pos0'(cap_stem,0);
  416. lft x1l=hround max(2u,3u-.5cap_stem'); top y1=h; bot y2=0;
  417. x1l=x2l=x0l=x0'l; y0=y0'=y7;
  418. penpos3(cap_band,90); penpos4(cap_band,90);
  419. penpos5(cap_curve if hefty:-3stem_corr fi,0);
  420. penpos6(.5[vair,cap_band],-90); penpos7(.5[vair,cap_band],-90);
  421. z3r=top z1; y4=y3; y5=.5[y4l,y6l]; y6=y7;
  422. x7=x2; y7l=vround .5h; x4=x6=.5w+.75u; x5r=hround(w-u);
  423. x4l:=x6l:=x4-.25cap_curve;
  424. filldraw stroke z1e--z0e--z0'e--z2e; % stem
  425. fill stroke z3e..pulled_arc.e(4,5) & pulled_arc.e(5,6)..z7e;  % lobe
  426. if serifs: nodish_serif(1,0,a,1/3,cap_jut,b,1/3,.5cap_jut);  % upper serif
  427.  dish_serif(2,0',c,1/3,cap_jut,d,1/3,cap_jut); fi  % lower serif
  428. math_fit(0,ic#-2.5u#); penlabels(0,1,2,3,4,5,6,7); endchar;
  429.  
  430. cmchar "The letter Q";
  431. beginchar("Q",14u#-width_adj#,cap_height#,comma_depth#);
  432. italcorr .7cap_height#*slant-.5u#;
  433. adjust_fit(0,0);
  434. numeric light_curve; light_curve=cap_curve-hround stem_corr;
  435. penpos1(vair',90); penpos3(vair',-90);
  436. penpos2(light_curve,180); penpos4(light_curve,0);
  437. if monospace: x2r=hround 1.5u;
  438.  interim superness:=sqrt superness;  % make |"Q"| like |"O"|
  439. else: x2r=hround u; fi
  440. x4r=w-x2r; x1=x3=.5w; y1r=h+o; y2=y4=.5h-vair_corr; y3r=-o;
  441. penstroke pulled_super_arc.e(1,2)(.5superpull)
  442.  & pulled_super_arc.e(2,3)(.5superpull)
  443.  & pulled_super_arc.e(3,4)(.5superpull)
  444.  & pulled_super_arc.e(4,1)(.5superpull) & cycle;  % bowl
  445. pickup tiny.nib;
  446. if hefty: penpos5(1.2(.5[cap_bar,light_curve]),0); penpos6(1.2light_curve,0);
  447.  x5=.5w; x6r=hround(w-1.5u);
  448.  y5=vround .28h; y6=-d;
  449.  fill diag_end(6r,5r,.25,1,5l,6l)--diag_end(5l,6l,.5,1,6r,5r)--cycle;  % tail
  450. else: pos3'(vair,270); pos5(vair,180); pos6(vair,90);
  451.  pos7(cap_curve,85); penpos8(eps,180);
  452.  z3'=z3; x6=x3; top y6r=vround(.2h+.5vair);
  453.  lft x5r=hround(.5w-1.25u-.5vair); y5=.5[y3,y6];
  454.  bot y7l=-d; x7l=2/3[x6,x8]; y8=0; rt x8=hround(x4r+.1u);
  455.  filldraw stroke z3'e{left}...z5e{up}...z6e{right}
  456.   ..z7e{right}...z8e{up}; fi % tail
  457. math_fit(-.3cap_height#*slant-.5u#,ic#);
  458. penlabels(1,2,3,4,5,6,7,8); endchar;
  459.  
  460. cmchar "The letter R";
  461. beginchar("R",if serifs: 12u#+.5max(2u#,cap_curve#)
  462.  else:12.5u#-.5width_adj# fi,cap_height#,0);
  463. italcorr .75cap_height#*slant- if serifs: 1.75 else: .5 fi\\ u#;
  464. adjust_fit(cap_serif_fit#,0);
  465. pickup tiny.nib; pos1(cap_stem',0); pos2(cap_stem',0);
  466. lft x1l=lft x2l=hround max(2u,3u-.5cap_stem'); top y1=h; bot y2=0;
  467. filldraw stroke z1e--z2e; % stem
  468. penpos3(cap_band,90); penpos4(cap_band,90);
  469. penpos5(cap_curve if hefty:-3stem_corr fi,0);
  470. penpos6(vair,-90); penpos7(vair,-90);
  471. z3r=top z1; y4=y3; y5=.5[y4l,y6l]; y6=y7;
  472. x7=x2; y7l=vround(.5h+.5vair); x4=x6;
  473. if serifs: x4=.5w-.5u; x5r=hround(w-2.25u);
  474. else: x4=.5w+.5u; x5r=hround(w-u); fi
  475. x4l:=x6l:=x4-.125cap_curve;
  476. fill stroke z3e..pulled_arc.e(4,5) & pulled_arc.e(5,6)..z7e;  % lobe
  477. if serifs: pos6'(vair,-90); pos0(cap_stem,180);
  478.  pos8(cap_curve,180); pos9(vair,-90); pos10(hair,0);
  479.  z6'=z6; lft x0r=lft x8r=hround(x5-2/3u-.5cap_curve);
  480.  y8=1/3[y2,y7]; y0=3/5[y2,y7]; x9=.5[x8l,x10r];
  481.  bot y9r=-o; rt x10r=hround(w-.05u); y10=1/4[y2,y7];
  482.  filldraw stroke z6'e{right}..z0e---z8e....z9e{right}..z10e{up};  % tail
  483.  nodish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut);  % upper serif
  484.  dish_serif(2,1,c,1/3,cap_jut,d,1/3,cap_jut);  % lower serif
  485. else: penpos8(cap_stem-2stem_corr,0); penpos9(cap_stem,0);
  486.  x8=x6+.5u; y8=y6; x9r=hround(w-.5u); y9=0;
  487.  fill z8l--diag_end(8l,9l,.5,1,9r,8r)--z8r--cycle; fi  % tail
  488. math_fit(0,.75ic#); penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
  489.  
  490. cmchar "The letter S";
  491. beginchar("S",10u#,cap_height#,0);
  492. italcorr cap_height#*slant-u#;
  493. adjust_fit(0,0);
  494. numeric theta; theta=90-angle(50u,h); slope:=-h/50u;  % angle at middle
  495. numeric s_slab; s_slab=if serifs:slab else:vround .2[slab,cap_stem] fi;
  496. numeric ess'; ess'=max(fine.breadth,cap_ess);
  497. pickup fine.nib; pos2(max(fine.breadth,s_slab-vround vair_corr),-90);
  498. pos0(ess',theta); pos7(s_slab,-90);
  499. x2+x7=2x0=w; x7-x2=if serifs: u else: 0 fi; top y2l=h+o; bot y7r=-o;
  500. y0=.52h; lft x3l=hround u; rt x6r=hround(w-u);
  501. x3r-x3l=x6r-x6l=hround .5[s_slab,ess']-fine;
  502. ellipse_set(2l,3l,4l,0l); ellipse_set(2r,3r,4r,0r); y3=y3r;
  503. ellipse_set(7l,6l,5l,0l); ellipse_set(7r,6r,5r,0r); y6=y6r;
  504. filldraw stroke super_arc.e(2,3) & z3e{down}
  505.  ..z4e---z5e..z6e{down} & super_arc.e(6,7);  % main stroke
  506. if serifs: pos1(hair,180); pos8(hair,180);
  507.  rt x1l=hround(w-1.5u); lft x8r=hround u;
  508.  bot y1=vround 2/3h+1; top y8=vround 1/3h-1;
  509.  filldraw stroke z1e{x2-x1,10(y2-y1)}....{left}z2e;  % upper arc
  510.  filldraw stroke z7e{left}....{up}z8e;  % lower arc
  511.  path upper_arc, lower_arc;
  512.  upper_arc=z1{x2-x1,10(y2-y1)}....{left}z2;
  513.  lower_arc=z7{left}....{up}z8;
  514.  pos10(.3[fine.breadth,cap_hair],0); pos9(.3[fine.breadth,cap_hair],0);
  515.  x10r=x1l; top y10=top y2l; x9l=x8r; bot y9=bot y7r;
  516.  x1l-x1'=x8'-x8r=1.6cap_curve-fine; y1'=y1; y8'=y8;
  517.  numeric t; t=xpart(upper_arc intersectiontimes(z10l--z1'));
  518.  filldraw z1l--z10r--z10l--subpath(t,0) of upper_arc--cycle;  % upper barb
  519.  t:=xpart(lower_arc intersectiontimes(z9r--z8'));
  520.  filldraw z8r--z9l--z9r--subpath(t,1) of lower_arc--cycle;  % lower barb
  521. else: pos1(1.2flare,-100); pos8(1.2flare,-100);
  522.  x1l=good.x(x1l+w-1.75u-rt x1); lft x8r=hround .8u;
  523.  top y1l=vround .93h+o; bot y8r=vround .1h-o;
  524.  filldraw stroke term.e(2,1,right,.9,4);  % upper arc and terminal
  525.  filldraw stroke term.e(7,8,left,1,4); fi  % lower arc and terminal
  526. math_fit(0,.5ic#); penlabels(0,1,1',2,3,4,5,6,7,8,8',9,10); endchar;
  527.  
  528. cmchar "The letter T";
  529. beginchar("T",13u#-width_adj#,cap_height#,0);
  530. italcorr cap_height#*slant-beak_jut#-.25u#;
  531. adjust_fit(0,0);
  532. h:=vround(h-2stem_corr);
  533. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  534. lft x1l=lft x2l=hround(.5w-.5cap_stem); top y1=h; bot y2=0;
  535. filldraw stroke z1e--z2e; % stem
  536. pickup crisp.nib; pos3(slab,90); pos4(hair,0);
  537. top y3r=h; x3=x1; rt x4r=hround(w-.65u); y4=good.y(y3l-beak)-eps;
  538. arm(3,4,e,beak_darkness,.7beak_jut);  % right arm and beak
  539. pos5(hair,180); x5=w-x4; y5=y4;
  540. arm(3,5,f,beak_darkness,-.7beak_jut);  % left arm and beak
  541. if serifs: dish_serif(2,1,c,1/3,1.414cap_jut,d,1/3,1.414cap_jut);  % lower serif
  542.  nodish_serif(1,2,a,1/3,.5cap_jut,b,1/3,.5cap_jut); fi  % upper bracketing
  543. math_fit(-.75cap_height#*slant,ic#-2.5u#); penlabels(1,2,3,4,5,6); endchar;
  544.  
  545. cmchar "The letter U";
  546. beginchar("U",13u#+.5width_adj#,cap_height#,0);
  547. italcorr cap_height#*slant-cap_serif_fit#+cap_jut#-2.5u#+min(.5cap_stem#,u#);
  548. if monospace: adjust_fit(cap_serif_fit#-.5u#,cap_serif_fit#-.5u#)
  549. else: adjust_fit(cap_serif_fit#,cap_serif_fit#) fi;
  550. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  551. pos2'(cap_stem,180); z2'=z2;
  552. pos3(cap_band,-90);
  553. pos4(cap_hair,0); pos5(cap_hair,0);
  554. x1=x2; x3=.5[x1,x5]; x4=x5; x1l=w-x5r;
  555. top y1=top y5=h; y2=y4=1/3h; bot y3r=-o;
  556. lft x1l=hround max(2u,3u-.5cap_stem);
  557. filldraw stroke z1e--z2e; % left stem
  558. filldraw stroke pulled_arc.e(2',3)
  559.  & pulled_arc.e(3,4)&z4e--z5e; % arc and right stem
  560. if serifs: dish_serif(1,2,a,1/3,cap_jut,b,1/3,cap_jut); % left serif
  561.  dish_serif(5,4,c,1/2,cap_jut,d,1/2,cap_jut)(dark); fi  % right serif
  562. math_fit(-cap_serif_fit#-.3cap_height#*slant-min(cap_height#*slant,u#),
  563.  max(.5ic#-.5u#,0)); penlabels(1,2,3,4,5); endchar;
  564.  
  565. cmchar "The letter V";
  566. beginchar("V",13u#,cap_height#,0);
  567. italcorr cap_height#*slant+.25u#;
  568. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  569. numeric left_stem,right_stem,outer_jut,alpha;
  570. left_stem=cap_stem-stem_corr;
  571. right_stem=min(cap_hair if hefty:-2stem_corr fi,left_stem);
  572. outer_jut=.75cap_jut; x1l=w-x4r=l+letter_fit+outer_jut+.25u; y1=y4=h;
  573. x2-x1=x4-x3; x2l+apex_corr=x3l; y2=y3=-apex_o;
  574. alpha=diag_ratio(2,right_stem,y1-y2,x4r-x1l-apex_corr);
  575. penpos1(alpha*left_stem,0); penpos2(alpha*left_stem,0);
  576. penpos3(alpha*right_stem,0); penpos4(alpha*right_stem,0);
  577. z0=whatever[z1r,z2r]=whatever[z3l,z4l];
  578. if y0>cap_notch_cut: y0:=cap_notch_cut;
  579.   fill z0+.5right{up}...{z4-z3}diag_end(3l,4l,1,1,4r,3r)
  580.     --diag_end(4r,3r,1,1,2l,1l)--diag_end(2l,1l,1,1,1r,2r){z2-z1}
  581.     ...{down}z0+.5left--cycle; % left and right diagonals
  582. else: fill z0--diag_end(0,4l,1,1,4r,3r)--diag_end(4r,3r,1,1,2l,1l)
  583.     --diag_end(2l,1l,1,1,1r,0)--cycle; fi % left and right diagonals
  584. if serifs: numeric inner_jut; pickup tiny.nib;
  585.  prime_points_inside(1,2); prime_points_inside(4,3);
  586.  if rt x1'r+cap_jut+.5u+1<=lft x4'l-cap_jut: inner_jut=cap_jut;
  587.  else: rt x1'r+inner_jut+.5u+1=lft x4'l-inner_jut; fi
  588.  dish_serif(1',2,a,1/3,outer_jut,b,1/2,inner_jut);  % left serif
  589.  dish_serif(4',3,c,.6,inner_jut,d,1/2,outer_jut)(dark); fi  % right serif
  590. math_fit(.75u#-cap_height#*slant,ic#-4u#); penlabels(0,1,2,3,4); endchar;
  591.  
  592. cmchar "The letter W";
  593. beginchar("W",18u#,cap_height#,0);
  594. italcorr cap_height#*slant+.25u#;
  595. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  596. numeric stem[],outer_jut,upper_notch,alpha,mid_corr;
  597. outer_jut=.7cap_jut; x1l=w-x8r=l+letter_fit+outer_jut+.25u;
  598. stem1=fudged.cap_stem-stem_corr;
  599. stem4=min(fudged.hair if hefty:-2stem_corr fi,stem1);
  600. stem2=stem4 if hefty:-2stem_corr fi;
  601. stem3=stem1 if hefty:-2stem_corr fi;
  602. x2-x1=x4-x3=x6-x5=x8-x7; x2l+apex_corr=x3l; x6l+apex_corr=x7l;
  603. y1=y8=h; y2=y3=y6=y7=-apex_o; y4=y5=if monospace: vround .6 fi\\ h;
  604. mid_corr=if monospace or hefty:-apex_corr else: 1/3jut fi;
  605. alpha=diag_ratio(4,stem2-stem3+stem4,y1-y2,x8r-x1l+mid_corr-2apex_corr);
  606. penpos1(alpha*stem1,0); penpos2(alpha*stem1,0);
  607. penpos3(alpha*stem2,0); penpos4(alpha*stem2,0);
  608. penpos5(alpha*stem3,0); penpos6(alpha*stem3,0);
  609. penpos7(alpha*stem4,0); penpos8(alpha*stem4,0);
  610. x4l-x1l=floor(x4l-x1l+.5(x5r+mid_corr-x4r)); % |x5r+mid_corr| $\approx$ |x4r|
  611. z23=whatever[z1r,z2r]=whatever[z3l,z4l];
  612. z45=whatever[z3r,z4r]=whatever[z5l,z6l];
  613. z67=whatever[z5r,z6r]=whatever[z7l,z8l]; upper_notch=y4-cap_notch_cut;
  614. fill diag_end(1l,2l,1,1,3r,4r){z4-z3}
  615.  ...if y45<upper_notch:(x45,upper_notch)+.5left{up}
  616.    --(x45,upper_notch)+.5right{down} else: z45&z45 fi
  617.  ...{z6-z5}diag_end(5l,6l,1,1,7r,8r)--diag_end(7r,8r,1,1,8l,7l){z7-z8}
  618.  ...if y67>cap_notch_cut:(x67,cap_notch_cut)+.5right{down}
  619.    --(x67,cap_notch_cut)+.5left{up} else: z67&z67 fi
  620.  ...{z5-z6}special_diag_end(6,5,4,3){z3-z4}
  621.  ...if y23>cap_notch_cut:(x23,cap_notch_cut)+.5right{down}
  622.    --(x23,cap_notch_cut)+.5left{up} else: z23&z23 fi
  623.  ...{z1-z2}diag_end(2r,1r,1,1,1l,2l)--cycle;  % diagonals
  624. if serifs: numeric inner_jut[]; pickup tiny.nib;
  625.  prime_points_inside(1,2); prime_points_inside(5,6); prime_points_inside(8,7);
  626.  if monospace: inner_jut1=inner_jut4=1.5cap_jut;
  627.  elseif hefty: inner_jut1=inner_jut4=cap_jut;
  628.  else: fill diag_end(6r,5r,1,1,5l,6l)--.9[z5l,z6l]
  629.    ..{z5-z6}.1[z5r,z6r]--cycle;  % middle stem
  630.   inner_jut2=.7inner_jut1; inner_jut4=1.1inner_jut3;
  631.   if rt x1'r+cap_jut+.5u+1<=lft x5'l-.7cap_jut: inner_jut1=cap_jut;
  632.   else: rt x1'r+inner_jut1+.5u+1=lft x5'l-inner_jut2; fi
  633.   if rt x5'r+cap_jut+.5u+1<=lft x8'l-1.1cap_jut: inner_jut3=cap_jut;
  634.   else: rt x5'r+inner_jut3+.5u+1=lft x8'l-inner_jut4; fi
  635.   dish_serif(5',6,e,1/3,inner_jut2,f,1/2,inner_jut3); fi  % middle serif
  636.  dish_serif(1',2,a,1/3,outer_jut,b,1/2,inner_jut1);  % left serif
  637.  dish_serif(8',7,c,.6,inner_jut4,d,1/2,outer_jut)(dark); fi  % right serif
  638. math_fit(.75u#-cap_height#*slant,ic#-2.5u#);
  639. penlabels(0,1,2,3,4,5,6,7,8,23,45,67); endchar;
  640.  
  641. cmchar "The letter X";
  642. beginchar("X",13u#,cap_height#,0);
  643. italcorr cap_height#*slant-.25u#;
  644. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  645. numeric stem[],outer_jut,xjut,alpha[];
  646. stem1=cap_stem-2stem_corr; stem2=min(cap_hair,stem1);
  647. outer_jut=.75cap_jut; xjut= if serifs: (stem1-stem2)/4 else: 0 fi;
  648. x1l=l+letter_fit+.5u+outer_jut; x2r=r-letter_fit-u-outer_jut-xjut;
  649. x3l=l+letter_fit+.25u+outer_jut+xjut; x4r=r-letter_fit-.25u-outer_jut;
  650. y1=y2=h; y3=y4=0;
  651. alpha1=diag_ratio(1,stem1,h,x4r-x1l);
  652. alpha2=diag_ratio(1,stem2,h,x2r-x3l);
  653. penpos1(alpha1*stem1,0); penpos2(alpha2*stem2,0);
  654. penpos3(alpha2*stem2,0); penpos4(alpha1*stem1,0);
  655. if hefty: z0=whatever[z1,z4]=whatever[z2,z3];
  656.  x12=x34=x0; y13=y24=y0;
  657.  z12=whatever[z2l,z3l]; z13=whatever[z2l,z3l];
  658.  z24=whatever[z2r,z3r]; z34=whatever[z2r,z3r];
  659.  forsuffixes $=13,24,34: z$'=.1[z$,z0]; endfor
  660.  fill diag_end(12,1r,.5,1,1l,13')--z13'--diag_end(13',3l,1,.5,3r,34')--z34'
  661.   --diag_end(34',4l,.5,1,4r,24')--z24'
  662.   --diag_end(24',2r,1,.5,2l,12)--z12--cycle; % diagonals
  663. else: fill diag_end(4r,1r,.5,1,1l,4l)
  664.   --diag_end(1l,4l,.5,1,4r,1r)--cycle; % left diagonal
  665.  fill diag_end(2l,3l,.5,1,3r,2r)
  666.   --diag_end(3r,2r,.5,1,2l,3l)--cycle; fi  % right diagonal
  667. if serifs: numeric inner_jut[]; pickup tiny.nib;
  668.  prime_points_inside(1,4); prime_points_inside(2,3);
  669.  prime_points_inside(3,2); prime_points_inside(4,1);
  670.  if rt x1'r+cap_jut+.5u+1<=lft x2'l-cap_jut-xjut: inner_jut1=cap_jut;
  671.  else: rt x1'r+inner_jut1+.5u+1=lft x2'l-inner_jut1-xjut; fi
  672.  if rt x3'r+cap_jut+.5u+1<=lft x4'l-cap_jut-xjut: inner_jut2=cap_jut;
  673.  else: rt x3'r+inner_jut2+.5u+1=lft x4'l-inner_jut2-xjut; fi
  674.  dish_serif(1',4,a,1/3,outer_jut,b,2/3,inner_jut1);  % upper left serif
  675.  dish_serif(4',1,c,2/3,inner_jut2,d,1/3,outer_jut);  % lower right serif
  676.  dish_serif(2',3,e,2/3,inner_jut1+xjut,
  677.   f,1/2,outer_jut+xjut)(dark);  % upper right serif
  678.  dish_serif(3',2,g,1/2,outer_jut+xjut,
  679.   h,2/3,inner_jut2+xjut)(dark); fi  % lower left serif
  680. math_fit(0,.5ic#); penlabels(0,1,2,3,4,12,13,24,34); endchar;
  681.  
  682. cmchar "The letter Y";
  683. beginchar("Y",13u#,cap_height#,0);
  684. italcorr cap_height#*slant+.45u#;
  685. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  686. numeric left_stem,right_stem,outer_jut,dy,alpha;
  687. left_stem=cap_stem-stem_corr;
  688. right_stem=min(cap_hair if hefty:-2stem_corr fi,left_stem);
  689. outer_jut=.75cap_jut; x1l=w-x4r=l+letter_fit+outer_jut+.05u;
  690. x2l=x5l=hround(.5w-.5left_stem); x3r=x5r; y1=y4=h; y2=y3=y5=.4h;
  691. dy=y1-y2; alpha=((x2l-x1l)++dy)/dy;
  692. penpos1(alpha*left_stem,0); penpos2(alpha*left_stem,0);
  693. penpos3(alpha*right_stem,0); penpos4(alpha*right_stem,0);
  694. penpos5(left_stem,0); penpos6(left_stem,0); x5=x6; y6=0;
  695. z0=whatever[z1r,z2r]=whatever[z3l,z4l];
  696. if y0>y2+cap_notch_cut: y0:=y2+cap_notch_cut;
  697.   fill z0+.5right{up}...{z4-z3}diag_end(3l,4l,1,1,4r,3r)--z5r
  698.     --diag_end(5r,6r,1,1,6l,5l)--z5l--diag_end(2l,1l,1,1,1r,2r){z2-z1}
  699.     ...{down}z0+.5left--cycle; % diagonals and stem
  700. else: fill z0--diag_end(0,4l,1,1,4r,3r)--z5r
  701.     --diag_end(5r,6r,1,1,6l,5l)--z5l
  702.     --diag_end(2l,1l,1,1,1r,0)--cycle; fi  % diagonals and stem
  703. if serifs: numeric inner_jut; pickup tiny.nib;
  704.  prime_points_inside(1,2); prime_points_inside(4,3); prime_points_inside(6,5);
  705.  if rt x1'r+cap_jut+.5u+1<=lft x4'l-cap_jut: inner_jut=cap_jut;
  706.  else: rt x1'r+inner_jut+.5u+1=lft x4'l-inner_jut; fi
  707.  dish_serif(1',2,a,1/3,outer_jut,b,1/2,inner_jut);  % upper left serif
  708.  dish_serif(4',3,c,.6,inner_jut,d,1/2,outer_jut)(dark);  % upper right serif
  709.  dish_serif(6',5,e,1/3,cap_jut,f,1/3,cap_jut); fi  % lower serif
  710. math_fit(.5u#-cap_height#*slant,ic#-4u#);
  711. penlabels(0,1,2,3,4,5,6); endchar;
  712.  
  713. cmchar "The letter Z";
  714. beginchar("Z",11u#,cap_height#,0);
  715. italcorr cap_height#*slant-.5u#;
  716. adjust_fit(0,0);
  717. numeric arm_thickness[],z_stem;
  718. if hefty: arm_thickness1=Vround(slab-vair_corr); arm_thickness2=slab;
  719.  z_stem=.8[vair,cap_stem];
  720. else: arm_thickness1=slab; arm_thickness2=vround(slab+vair_corr);
  721.  z_stem=.9[vair,cap_stem]; fi
  722. pickup tiny.nib; x3l=x4l=w-x1r=w-x2r; lft x3l=hround u;
  723. top y1=h; y2=min(y1,h-2/3arm_thickness1);
  724. bot y4=0; y3=max(y4,2/3arm_thickness2);
  725. numeric alpha; alpha=diag_ratio(1,z_stem-tiny,y2-y3,x2r-x3l);
  726. penpos1(alpha*(z_stem-tiny),0); penpos2(alpha*(z_stem-tiny),0);
  727. penpos3(alpha*(z_stem-tiny),0); penpos4(alpha*(z_stem-tiny),0);
  728. pair delta; delta=penoffset z3-z2 of currentpen;
  729. fill top lft z1l--z2l+delta---z3l+delta..lft z3l---lft z4l..bot z4l
  730.  ---bot rt z4r--z3r-delta---z2r-delta..rt z2r---rt z1r..top z1r
  731.  ---cycle;  % diagonal
  732. pickup crisp.nib; pos5(arm_thickness1,90); pos6(hair,180);
  733. top y5r=h; x5=x1; lft x6r=hround 1.25u; y6=good.y(y5l-beak)-eps;
  734. arm(5,6,a,beak_darkness**.8,-.4beak_jut);  % upper arm and beak
  735. pos7(arm_thickness2,-90); pos8(hair,0);
  736. bot y7r=0; x7=x4; rt x8r=hround(w-.9u); y8=good.y(y7l+1.2beak)+eps;
  737. arm(7,8,b,beak_darkness**.9,.6beak_jut);  % lower arm and beak
  738. math_fit(0,.5ic#); penlabels(1,2,3,4,5,6,7,8); endchar;
  739.